Caprice 32 - emulateur trop ancien

Bonjour,

Je souhaite jouer à des jeux amstrad 6128. Mais à la place de caprice32 et de crocods je souhaiterais utiliser Caprice_Forever_v24.2_2.

En effet avec les autres
-> soit je ne peux pas lancer de jeux ùcpm
-> soit la barre d'espace est configuré pour faire une avance rapide, mais dans la rom elle sert à lancer la disquette n°2
-> il n'y a pas de menu pour changer de disquette

Bref... pas top

J'aimerais donc utiliser cet autre émulateur, quitte à modifier (malheureusement) les fichiers de config

Hello
Tu peux donner un exemple de jeu que tu souhaites lancer (avec extension) ?

Asterix Chez Rahazade (F) (1988) (Disk 1 of 2) (ùCPM).dsk
avec capri : impossible de faire ùcpm
avec croco : ùcpm ne lance rien
avec le caprice forever: Ok

Pirates (F) (1987) (Disk 1 of 2) [a2].dsk
avec capri : peut pas rentrer le nom du pirate, pas toute les touches répondent
croco : joystick non reconnu
avec le caprice forever : Ok

Bob Winner (F) (1986) (Disk 1 of 2) [a2].dsk
avec capri : ne fonctionne pas car on ne peut pas faire espace
avec croco : ne fonctionne pas car on ne peut pas faire espace
avec le caprice forever : Ok

Re

Dans tous les cas, il faut savoir que dès qu'il s'agit d'un ordinausaure, par défaut le focus clavier est désactivé (permettant l'usage de la manette).
Pour retrouver les options d'un clavier traditionnel, il faut activer le keyboard focus :
- soit par le menu Retrobat (cf copie d'écran ci-dessous)
- soit par la touche "arret defil" de ton clavier

tu pourras ainsi tapper la commande pour lancer le jeu.

Je regarde si, via l'usage d'un .M3U, il est possible d'automatiser le tout.

Super !!! Merci getupor. Chez moi (HP probook) la touche est TRES TRES BIEN cachée (j'ai aussi eu du mal à trouver le menu de ta capture d'écran )

Il faut que je fasse fn + c pour simuler l'action de cette touche.... nan sérieusement fn +c ils l'ont cherché où ce raccourcie ???

Bon ceci dit c'est bon pour la touche espace et le nom du pirate, mais je ne peux pas lancer astérix qui est un jeu qui se lance avec ùcpm ou |cpm, le jeu ne se lance pas

De plus, comment je fais pour changer de disquette ? le menu 'Disk' n'est pas présent dans l'émulateur capri. J'ai vu le .m3u, mais pareil, je ne vois pas comment sélectionner la suite des disquettes une fois le fichier créer.

Fichier "Pirates.m3u" déposer au même niveau que les .dsk et qui contient les lignes suivantes :
Pirates (F) (1987) (Disk 1 of 2) [a2].dsk
Pirates (F) (1987) (Disk 2 of 2) [a2].dsk

Partiellement résolu

Pour Asterix, j'ai crée un m3u avec a l'interieur, et lancé avec Cap32

Code:

#COMMAND:|CPM
Asterix Chez Rahazade (1988)(Coktel Vision)(fr)(Disk 1 of 2)[cpm version].dsk
Asterix Chez Rahazade (1988)(Coktel Vision)(fr)(Disk 2 of 2)[cpm version].dsk

Bon, malheureusement ça ne lance pas la commande CPM automatiquement (contrairement à ce qui est indiqué sur la doc libretro). Mais pas grave, vu que j'ai accès au clavier, en faisant Maj + ^, ça permet l'utilisation du caractère | (reste a tapper le reste de la commande, et si le clavier est resté en qwerty, utiliser la touche ; à la place du M)

Pour le changement de disque, il faut a nouveau utiliser "arret defil" pour pouvoir utiliser la manettes, et les hotkey pour les changements de disques (comme indiqué sur la notice)

Ah yes super... je ne l'aurai jamais trouvé seul et pourtant j'ai bien lu la doc libreto et le manuel d'instruction du forum !... Bon c'est pas ergonomique, c'est une solution de contournement et ça fonctionne.

Le + ça fait disparaître de la liste des jeux ceux contenus dans le .m3u
Le - faut relancer le scrapeur pour avoir le jeu comme les autres

Bon ça va le faire MERCI !!!

Sur la possibilité d'utiliser un émulateur externe ou de voir cet émulateur dans retrobat, ça peut le faire ?

Salut,

je ne crois pas que les émulateurs externes peuvent utiliser les fichiers .m3u

Ma méthode:

Pour faire les fichiers .m3u en batch tu peux l'utiliser comme ceci, il faut d'abord créer des dossiers pour chaque jeu avec le batch suivant:

@ECHO OFF

FOR %%F in (*.dsk) DO (
   SET "folder=%%~nF"
   CALL :MOVEFILE "%%F" "%%~nxF"
)

PAUSE
EXIT /B

:MOVEFILE
CALL :GETFIRST "%folder%"
>NUL 2>&1 MKDIR "%folder%"
>NUL MOVE /Y %1 "%folder%\%~2"
GOTO :EOF

:GETFIRST
SET "folder=%folder: (=" & REM."%"
SET "folder=%folder:&=#%"
CALL :TRIM %folder%
SET "folder=%folder:#=&%"
GOTO :EOF

:TRIM
SET folder=%*
GOTO :EOF

Après avec le batch suivant il va te faire des fichiers .m3u dans chaque dossier comme suivant:

@echo off
for /R "%~dp0" %%I in (*.dsk) do for %%J in ("%%~dpI.") do echo .data/%%~nxI>>"%%~dpI%%~nxJ.m3u"

Fichier .m3u créé:

.data/20000 Lieus Sous Les Mers (1988)(Coktel Vision)(Disk 1 of 2)[cpm version].dsk
.data/20000 Lieus Sous Les Mers (1988)(Coktel Vision)(Disk 2 of 2)[cpm version].dsk

Note que les jeux doivent maintenant se trouvent dans un dossier .data

Maintenant tu vas créer un dossier .data et tu mets tous les jeux à multi disques dedans (recherche avec .dsk et copie tout dans ce dossier).

A la fin tu mets tous les .m3u dans le dossier racine (recherche avec .m3u et copie tout dans le dossier racine).

Tu vas avoir un dossier Amstrad CPC, et dans ce dossier il va y avoir tous les fichiers .m3u et tu vas avoir un dossier .data avec tous les jeux multi-disques, comme celà c'est aussi bien propre et tu n'as pas besoin de cacher les fichiers .m3u en RetroBat.

Structure:

Amstrad CPC\
└─ .data\
      └─ 20000 Lieus Sous Les Mers (1988)(Coktel Vision)(Disk 1 of 2)[cpm version].dsk
      └─ 20000 Lieus Sous Les Mers (1988)(Coktel Vision)(Disk 2 of 2)[cpm version].dsk
      └─ A320 (1989)(Loriciels)(fr)(Disk 1 of 2)[cr NPS].dsk
      └─ A320 (1989)(Loriciels)(fr)(Disk 2 of 2)[cr NPS].dsk
      └─ Airborne Ranger (1988)(Microprose)(Disk 1 of 2).dsk
      └─ Airborne Ranger (1988)(Microprose)(Disk 2 of 2).dsk
└─ 20000 Lieus Sous Les Mers.m3u
└─ A320.m3u    
└─ Airborne Ranger.m3u

ouais c'est chouette ce script !!!

Je l'ai adapté pour éviter le dossier .data et j'ai mis la ligne du script 2 dans le premier. Mais c'est génial !!!

Merci

Pour ce qui de l'émulateur externe caprice forever est quand même plus performant que capri32 et j'aimerais l'utilisé en lieu et place. A priori pas compatible avec les m3u, mais il a le menu "disk" qui permet de charger les dsk. Ca évite de devoir switcher en permanence avec fn +c

Super, moi je préfères avoir un dossier .data pour garder tout un peu plus propre, comme ça je dis à Retrobat de m'afficher les .m3u et je ne vois pas les 2 ou même plusieurs disques des jeux, mais moi j'utilises aussi Retroarch pour tout ce qui est .m3u

J'ai modifié le script "à ma sauce"...

Il fait pareil, mais comme ça je comprends ce qu'il fait

Code:


@ECHO OFF

REM Initilaisation
SET ancien_dossier=

REM Création des fichiers de test
REM echo rien>>"Bob Winner (F) (1986) (Disk 1 of 2) [a2].dsk"
REM echo rien>>"Bob Winner (F) (1986) (Disk 2 of 2) [a2].dsk"
REM echo rien>>"Pirates (F) (1987) (Disk 1 of 2) [a2].dsk"
REM echo rien>>"Pirates (F) (1987) (Disk 2 of 2) [a2].dsk"

FOR %%F in (*.dsk) DO (
   SET "dossier_local=%%~dpF"
   SET "rom=%%~nxF"
   SET "dossier=%%~nF"
   CALL :CREATE_M3U
)

REM Création du dernier m3u
DIR "%ancien_dossier%" /B >"%ancien_dossier%.m3u"
> NUL MOVE "%ancien_dossier%.m3u" "%dossier_local%%ancien_dossier%"
echo Cr‚ation du fichier %ancien_dossier%.m3u
echo.
echo Tous les jeux multi-support sont convertis
echo.

PAUSE
EXIT /B


:CREATE_M3U
REM Epurage du nom de la rom pour n'avoir que le nom du dossier
SET "dossier=%dossier: (=" & REM."%"
SET "dossier=%dossier:&=#%"
CALL :TRIM %dossier%
SET "dossier=%dossier:#=&%"

REM v‚rification si changement de dossier
IF "%ancien_dossier%"=="%dossier%" (
   REM echo les dossiers sont identiques
   REM D‚placement de la rom dans le dossier
   echo Traitement de : "%rom%"
   >NUL MOVE /Y "%rom%" "%dossier%\"
) ELSE (
   REM echo les dossiers sont differents
   REM cr‚ation du dossier et d‚placement de la rom dedans
   >NUL 2>&1 MKDIR "%dossier%"
   >NUL MOVE /Y "%rom%" "%dossier%\"
   IF "%ancien_dossier%"=="" (
      REM c'est le premier passage
      echo Traitement de : "%rom%"
   ) ELSE (
      REM ce n'est pas premier passage, il faut aller traiter le dossier pr‚c‚dent pour cr‚er le m3u
      DIR "%ancien_dossier%" /B >"%ancien_dossier%.m3u"
      > NUL MOVE "%ancien_dossier%.m3u" "%dossier_local%%ancien_dossier%"
      echo Cr‚ation du fichier %ancien_dossier%.m3u
      echo.
      echo Traitement de : "%rom%"
   )
   SET ancien_dossier=%dossier%
)
GOTO :EOF

:TRIM
SET dossier=%*
GOTO :EOF


Salut,

je viens de l'essayer, il fait effectivement pareil et il marche top

Podgers95 wrote:Pour ce qui de l'émulateur externe caprice forever est quand même plus performant que capri32 et j'aimerais l'utilisé en lieu et place. A priori pas compatible avec les m3u, mais il a le menu "disk" qui permet de charger les dsk. Ca évite de devoir switcher en permanence avec fn +c

Hello
Faudrait qu'on dev se penche dessus, mais :
-est-ce qu'il s'agit d'un emulateur "portable" (c'est a dire qui embarque ses propres fichiers de configuration sans avoir a les installer dans les dossiers systèmes)
-est-ce qu'il peut être exécuté en ligne de commande.
Ce sont les deux pré-requis indispensables pour une intégration.

Hi,

je ne sais pas si Caprice Forever est portable, mais je supposes qu'on peut l'utiliser comme celà. Il supporte les lignes de commande, au moins la version modifiée, Caprice Forever v0.29

Edit: Je viens de regarder car je l'ai aussi installé, je l'utilises avec LaunchBox sur mon PC et je n'ai trouvé aucune trace sur mon disque système.

Ah mais c'est plutôt une bonne chose alors si je comprends ? Un espoir de le voir ajouté ?