Add m3u Manager in BatGui / Add Retroachievments Name / Hash Checker

Hey guys,

I know this is nitpicking as retrobat is the absolute best out here, but I whis there was:

A: a automatic M3U Generator for large collections, it scans file names and creates a m3u playlist for multidisc games.

B: a Retroachievment Comptability Checker that picks out roms/ games that are stored on drive + listed on the website as compatible but arent the correct hash code as rom.


Maybe future updates could implement this as a function for batgui?


Thanks in advance

LouisVmigo wrote:A: a automatic M3U Generator for large collections, it scans file names and creates a m3u playlist for multidisc games.

Hi,

put your multidisk games in a folder and run this batch, it's gonna create a folder for each single game and will generate a .m3u file inside together with the mutlidisk games files.

Code:

@ECHO OFF

SET old_folder=

FOR %%F in (*.dsk) DO (
   SET "local_folder=%%~dpF"
   SET "rom=%%~nxF"
   SET "folder=%%~nF"
   CALL :CREATE_M3U
)

DIR "%old_folder%" /B >"%old_folder%.m3u"
> NUL MOVE "%old_folder%.m3u" "%local_folder%%old_folder%"
echo M3U file creation of %old_folder%.m3u
echo.
echo All the multi-disk games have been converted
echo.

PAUSE
EXIT /B

:CREATE_M3U
SET "folder=%folder: (=" & REM."%"
SET "folder=%folder:&=#%"
CALL :TRIM %folder%
SET "folder=%folder:#=&%"

IF "%old_folder%"=="%folder%" (
   echo Processing of : "%rom%"
   >NUL MOVE /Y "%rom%" "%folder%\"
) ELSE (
   >NUL 2>&1 MKDIR "%folder%"
   >NUL MOVE /Y "%rom%" "%folder%\"
   IF "%old_folder%"=="" (
   echo Processing of : "%rom%"
   ) ELSE (
      DIR "%old_folder%" /B >"%old_folder%.m3u"
      > NUL MOVE "%old_folder%.m3u" "%local_folder%%old_folder%"
      echo M3U file creation of %old_folder%.m3u
      echo.
      echo Processing of : "%rom%"
   )
   SET old_folder=%folder%
)
GOTO :EOF

:TRIM
SET folder=%*
GOTO :EOF

Thank you!!